adric22 wrote:I certainly can.. however, I warn you now the load/save routine is apparently broken.
Right you are. Your save routine defines the X/Y register pair twice, first time with the start, second time with the end address without storing the start address away - this can't work.
Furthermore, it isn't necessary to close the file yourselves, the kernal load, and save routines open, and close the file for you indeed.
Here we go:
Code: Select all
SETLFS = $FFBA
SETNAM = $FFBD
LOAD = $FFD5
SAVE = $FFD8
; relative LOAD (secondary address = 0)
LDA #1
LDX #{device-number}
LDY #0
JSR SETLFS
LDA #{length of file name}
LDX #<{location of file name}
LDY #>{location of file name}
JSR SETNAM
LDA #0
LDX #<{forced load address}
LDY #>{forced load address}
JSR LOAD
; absolute LOAD (secondary address = 1)
LDA #1
LDX #{device-number}
LDY #1
JSR SETLFS
LDA #{length of file name}
LDX #<{location of file name}
LDY #>{location of file name}
JSR SETNAM
LDA #0
JSR LOAD
; SAVE (always is absolute, but see below for the relevance of the secondary address)
LDA #1
LDX #{device-number}
LDY #{save secondary address}
JSR SETLFS
LDA #{length of file name}
LDX #<{location of file name}
LDY #>{location of file name}
JSR SETNAM
LDA #<{start address incl.}
STA $C1
LDA #>{start address incl.}
STA $C2
LDA #$C1
LDX #<{end address excl.}
LDY #>{end address excl.}
JSR SAVE
$C1, and $C2 are used to store the start address, because the values end up there anyway, when SAVE is called. With SAVE, secondary address = 0 is generally the default. With SAVE on tape, secondary address = 1 forces an absolute LOAD, even though a relative LOAD might have been specified! This is mainly used for autostarting tape turbos. Also on tape, secondary address = 2 writes an END OF TAPE marker behind the saved data.
The BASIC LOAD, and SAVE command both use logical channel 1 for their operations, a convention which can be adopted here without problems, as this is the intended use for channel 1.
It might be interesting for your program to provide the import of a whole 2K character set. Also the export of the screen as BASIC program is a very promising idea. I'm currently coding the character editor batch extension for MINIPAINT, which will allow editing all 256 characters. I had planned for them to be presented in the same look as your character selection screen.
All these programs together will give a nice level editor for everything.
Greetings,
Michael
P.S.: Hmm, the main part of this posting should probably also go into 'ROM calls & other tricks'.
