Denial

Code: Select all

//
// 2364 Mask ROM Reader PROGRAM
//
// 2019.01.13 @kanpapa
//
//                2364
#define D0 6     // 9
#define D1 7     // 10
#define D2 8     // 11
#define D3 9     // 13
#define D4 10     // 14
#define D5 11     // 15
#define D6 12     // 16
#define D7 13     // 17

#define AD0 5    // 8
#define AD1 4    // 7
#define AD2 3    // 6
#define AD3 2    // 5
#define AD4 20    // 4
#define AD5 21    // 3
#define AD6 22    // 2
#define AD7 23    // 1
#define AD8 19    // 23
#define AD9 18    // 22
#define AD10 15   // 19
#define AD11 14   // 18
#define AD12 17   // 21

#define CE 16  // 20 Chip Enable
               // 24 Vcc
               // 12 GND
#define CE1 24               


int DATA[]={D0,D1,D2,D3,D4,D5,D6,D7};
int ADDR[]={AD0,AD1,AD2,AD3, AD4,AD5,AD6,AD7, AD8,AD9,AD10,AD11, AD12};

void setAddress(int addr) {
  for (int bitno = 0 ; bitno < 16 ; bitno++){
    if (bitRead(addr, bitno) == 1) {
      digitalWrite(ADDR[bitno], HIGH);
    } else {
      digitalWrite(ADDR[bitno], LOW);
    }
  }
  return;
}

byte memRead(int addr) {
  digitalWrite(CE, HIGH);  // CE = High
  digitalWrite(CE1, HIGH);
  byte data = 0;
  setAddress(addr);
  
  digitalWrite(CE, HIGH);  // Block 6
  digitalWrite(CE1,LOW); //Block 7
  
  delayMicroseconds(100); // Wait 1micro sec
  for (int bitno = 0; bitno < 8; bitno++) {
    if (digitalRead(DATA[bitno]) == HIGH) {
      bitSet(data, bitno);
    }
  }
  digitalWrite(CE, HIGH);  // CE = High
  digitalWrite(CE1,HIGH);  
  return data;
}

void hexprint2(byte val){
  if (val < 16){
    Serial.print("0");
  }
  Serial.print(val, HEX);
}

void hexprint4(int val){
   hexprint2(highByte(val));
   hexprint2(lowByte(val));
}

void setup() {
  // Initalize serial
  Serial.begin(115200);
  while (!Serial) {
    ;
  }
    
  // set PINMMODE
  pinMode(CE, OUTPUT);
  pinMode(CE1, OUTPUT);

  digitalWrite(CE, HIGH);
  digitalWrite(CE1,HIGH);

  
  for (int i=0; i<13; i++) pinMode(ADDR[i], OUTPUT); // address
  for (int i=0; i<8; i++)  pinMode(DATA[i], INPUT);  // data

  // Output startup message
  Serial.println("2364 Mask ROM Reader PROGRAM");

  // Read memory 0x0000-0x1FFF (8KByte*8bit=64Kbit)
  int start_adrs = 0x0000;
  //Change to 0x1000 for 2332 (Such as Character ROM)
  int end_adrs = 0x2000;
  int max_count = 16;
  int total_count = end_adrs - start_adrs;
  Serial.print(total_count);
  Serial.println("Bytes");

  delay(1000);

  // Output Intel HEX Format
  int read_adrs = start_adrs;
  int tchksum = 0;


  while(total_count > 0){
    int lchksum = 0;
    int count = 0;

    // RECORD MARK
    Serial.print(":");
    
    // LOAD REDLEN
    if (total_count >= 16){
      count = max_count;
    } else {
      count = total_count;
    }    
    hexprint2(count);
    lchksum += count;

    // OFFSET
    hexprint4(read_adrs);
    lchksum += highByte(read_adrs);
    lchksum += lowByte(read_adrs);

    // RECTYP
    Serial.print("00");

    // DATA
    for (int i = 0 ; i < count ; i++){
      // Read data
      byte read_data = memRead(read_adrs + i);
      hexprint2(read_data);
      lchksum += read_data;
      // Add to the overall checksum (dumps carry)
      tchksum += read_data;
    }
   
    // CHKSUM
    lchksum = lowByte(~lchksum + 1 );
    hexprint2(lchksum);
    Serial.print("\n");

    //
    read_adrs += count;
    total_count = total_count - count;
  }

  // EOF
  Serial.println(":00000001FF");

  Serial.printf("Sum: %06x \n",tchksum);
  byte tmod = tchksum % 256;
  Serial.printf("Mod: %02x \n",tmod);
  tmod = ~tmod+1;
  Serial.printf("\n %02x 2's Comp \n",tmod);

}

void loop() {
}